184 lines
5.5 KiB
Fortran
184 lines
5.5 KiB
Fortran
SUBROUTINE SPOTRFF( UPLO, N, A, LDA, INFO )
|
|
*
|
|
* -- LAPACK routine (version 3.0) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
|
|
* Courant Institute, Argonne National Lab, and Rice University
|
|
* March 31, 1993
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER INFO, LDA, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL A( LDA, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* SPOTRF computes the Cholesky factorization of a real symmetric
|
|
* positive definite matrix A.
|
|
*
|
|
* The factorization has the form
|
|
* A = U**T * U, if UPLO = 'U', or
|
|
* A = L * L**T, if UPLO = 'L',
|
|
* where U is an upper triangular matrix and L is lower triangular.
|
|
*
|
|
* This is the block version of the algorithm, calling Level 3 BLAS.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* = 'U': Upper triangle of A is stored;
|
|
* = 'L': Lower triangle of A is stored.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A. N >= 0.
|
|
*
|
|
* A (input/output) REAL array, dimension (LDA,N)
|
|
* On entry, the symmetric matrix A. If UPLO = 'U', the leading
|
|
* N-by-N upper triangular part of A contains the upper
|
|
* triangular part of the matrix A, and the strictly lower
|
|
* triangular part of A is not referenced. If UPLO = 'L', the
|
|
* leading N-by-N lower triangular part of A contains the lower
|
|
* triangular part of the matrix A, and the strictly upper
|
|
* triangular part of A is not referenced.
|
|
*
|
|
* On exit, if INFO = 0, the factor U or L from the Cholesky
|
|
* factorization A = U**T*U or A = L*L**T.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
* > 0: if INFO = i, the leading minor of order i is not
|
|
* positive definite, and the factorization could not be
|
|
* completed.
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ONE
|
|
PARAMETER ( ONE = 1.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL UPPER
|
|
INTEGER J, JB, NB
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL SGEMM, SPOTF2, SSYRK, STRSM, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, MIN
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
INFO = 0
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -4
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'SPOTRF', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
* Determine the block size for this environment.
|
|
*
|
|
NB = 56
|
|
|
|
IF( NB.LE.1 .OR. NB.GE.N ) THEN
|
|
*
|
|
* Use unblocked code.
|
|
*
|
|
CALL SPOTF2( UPLO, N, A, LDA, INFO )
|
|
ELSE
|
|
*
|
|
* Use blocked code.
|
|
*
|
|
IF( UPPER ) THEN
|
|
*
|
|
* Compute the Cholesky factorization A = U'*U.
|
|
*
|
|
DO 10 J = 1, N, NB
|
|
*
|
|
* Update and factorize the current diagonal block and test
|
|
* for non-positive-definiteness.
|
|
*
|
|
JB = MIN( NB, N-J+1 )
|
|
CALL SSYRK( 'Upper', 'Transpose', JB, J-1, -ONE,
|
|
$ A( 1, J ), LDA, ONE, A( J, J ), LDA )
|
|
CALL SPOTF2( 'Upper', JB, A( J, J ), LDA, INFO )
|
|
IF( INFO.NE.0 )
|
|
$ GO TO 30
|
|
IF( J+JB.LE.N ) THEN
|
|
*
|
|
* Compute the current block row.
|
|
*
|
|
CALL SGEMM( 'Transpose', 'No transpose', JB, N-J-JB+1,
|
|
$ J-1, -ONE, A( 1, J ), LDA, A( 1, J+JB ),
|
|
$ LDA, ONE, A( J, J+JB ), LDA )
|
|
CALL STRSM( 'Left', 'Upper', 'Transpose', 'Non-unit',
|
|
$ JB, N-J-JB+1, ONE, A( J, J ), LDA,
|
|
$ A( J, J+JB ), LDA )
|
|
END IF
|
|
10 CONTINUE
|
|
*
|
|
ELSE
|
|
*
|
|
* Compute the Cholesky factorization A = L*L'.
|
|
*
|
|
DO 20 J = 1, N, NB
|
|
*
|
|
* Update and factorize the current diagonal block and test
|
|
* for non-positive-definiteness.
|
|
*
|
|
JB = MIN( NB, N-J+1 )
|
|
CALL SSYRK( 'Lower', 'No transpose', JB, J-1, -ONE,
|
|
$ A( J, 1 ), LDA, ONE, A( J, J ), LDA )
|
|
CALL SPOTF2( 'Lower', JB, A( J, J ), LDA, INFO )
|
|
IF( INFO.NE.0 )
|
|
$ GO TO 30
|
|
IF( J+JB.LE.N ) THEN
|
|
*
|
|
* Compute the current block column.
|
|
*
|
|
CALL SGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
|
|
$ J-1, -ONE, A( J+JB, 1 ), LDA, A( J, 1 ),
|
|
$ LDA, ONE, A( J+JB, J ), LDA )
|
|
CALL STRSM( 'Right', 'Lower', 'Transpose', 'Non-unit',
|
|
$ N-J-JB+1, JB, ONE, A( J, J ), LDA,
|
|
$ A( J+JB, J ), LDA )
|
|
END IF
|
|
20 CONTINUE
|
|
END IF
|
|
END IF
|
|
GO TO 40
|
|
*
|
|
30 CONTINUE
|
|
INFO = INFO + J - 1
|
|
*
|
|
40 CONTINUE
|
|
RETURN
|
|
*
|
|
* End of SPOTRF
|
|
*
|
|
END
|